Antagande:
Din poängmall står i A1:B5 (boskstäver i A1-A5 och poäng i B1-B5)
Resultatet/bokstaven i cell G1

Då kan du hämta ut poängen med den här formeln:
=LETARAD(G1;$A$1:$B$5;2;FALSKT)

Vill du slippa en extern poängtabell så kan du skapa tabellen i själva formeln:
=LETARAD(G1;{"a"\5;"b"\3;"c"\3;"d"\1;"e"\-10};2;FALSKT)

Dubbel

hej

eftersom du låst $A$1:$B$5 i sökområdet så ändras ju inte dessa. men däremot letauppvärdet ändras ju när du kopierar till en annan cell.

vill du ha exakt den formeln utan ändringar så gör du detta.

stall dig i den rutan formeln är. du ser formeln i inmatningsfältet.
Markera formeln i inmatningsfältet tryck ESC och gå till den cell där du vill kopiera in den och tryck CTRL+v så kopierar den in exakt den formel du hade från början.utan ändringar.

hoppas det hjälper dig

Om det är fler celler (12) än svarsalternativ (5st) så kan du testa att räkna A, b, c, d, e sepearat och sedan summera, typ:

=ANTAL.OM(G1:R1;"a")*5+ANTAL.OM(G1:R1;"b")*3+ANTAL.OM(G1:R1;"c")*3+ANTAL.OM(G1:R1;"d")*1+ANTAL.OM(G1:R1;"e")*-10

Eller så här om du tycker att det är snyggare:
=SUMMA(ANTAL.OM(G1:R1;"a")*5;ANTAL.OM(G1:R1;"b")*3;ANTAL.OM(G1:R1;"c")*3;ANTAL.OM(G1:R1;"d")*1;ANTAL.OM(G1:R1;"e")*-10)

Förstår inte riktigt vad ni diskuterar sedan: sök/ersätt G1:R1 -> A1:R1 ?

Om du vill ha en riktigt kompakt formel där områden, villkor och poäng bara skrivs in en gång så kan du göra så här:
=PRODUKTSUMMA((G1:R1={"a";"b";"c";"d";"e"})*{5;3;3;"1";"-10"})
Men formeln blir kanske svår att förstå? (jag TROR att jag vet vad jag gjort, men...).

Exempel på svårbegriplighet: Om man skulle lägga data i Kolumn A istället för Rad 1 så blir den första formeln rätt direkt om man byter ut adressen (sök/ersätt G1:R1 ->A1:A12)

=SUMMA(ANTAL.OM(A1:A12;"a")*5;ANTAL.OM(A1:A12;"b")*3;ANTAL.OM(A1:A12;"c")*3;ANTAL.OM(A1:A12;"d")*1;ANTAL.OM(A1:A12;"e")*-10)

Medan den andra formeln blir fel:
=PRODUKTSUMMA((A1:A12={"a";"b";"c";"d";"e"})*{5;3;3;"1";"-10"})
Om du inte samtidigt "byter riktning" på dina hjälpmatriser också:
=PRODUKTSUMMA((A1:A12={"a"\"b"\"c"\"d"\"e"})*{5\3\3\"1"\"-10"})

Den här typen av Matrisformler kan kännas självklara när man lärt sig men fullständigt obegripligt innan dess (här har excel lite pedagogik att sno från google calk).

Kör den formel du känner dig bekväm med. Kort kan vara elegant men ibland är det bättre att köra en lång formel som man förstår.

/A Nony Mouse

Underbart! Tack för hjälpen!