Personligen skulle jag använda mig av VBA för detta. Om du inte är någorlunda insatt i VBA-programmering kanske min lösning kan vara lite väl svår, men här följer en kort beskrivning..

Färgen på en stapel i ett diagram går att ändra genom att använda sig av:

Blad1.ChartObjects(1).Chart.SeriesCollection(1).Points(1).Interior.ColorIndex = 1

(Självklart måste du använda dig av namn och parametrar som stämmer överens med diagrammet i ditt dokument)

Skapa en metod innehållande if-satser eller en case-sats där värdet på källdatan kontrolleras och färgen på stapeln ändras enligt ovanstående. Anropa denna metod från Worksheet_change för automatisk uppdatering.

Hoppas du får det att funka! Återkom för en mer utförlig beskrivning om du får problem.

/Andreas

---

Ok. Här följer en kort guide..

1. Öppna ett nytt tomt Excel-dokument
2. Mata in en siffra i cell A1 på Blad1. Markera cellen och infoga ett stapeldiagram
3. Starta nu VBA-editorn (Alt+F11). Visa projekt-utforskaren (Ctrl+R)
4. Dubbelklicka på Blad1 och klistra in följande kod:

Private Sub Worksheet_Change(ByVal Target As Range)
    With Blad1.ChartObjects(1).Chart.SeriesCollection(1).Points(1).Interior
        If Range("A1").Value = 10 Then
            .ColorIndex = 10
        ElseIf Range("A1").Value > 10 Then
            .ColorIndex = 3
        Else
            .ColorIndex = 5
        End If
    End With
End Sub
       
Prova att mata in 9, 10 och 11 i cell A1 och se vad som händer..

Förhoppningsvis kan du sedan anpassa denna metod till att fungera på flera staplar, flera diagram etc.

/Andreas

 

 

---

 Hej Andreas! 

Jag skulle gärna vilja fråga dig hur jag skulle kunna utvidga den koden du gav här till att fungera på en hel kolumn? Tex att värdena under 1-2 blir röda, 3-4 blir gula och 5-6 blir gröna osv?

Skulle du kunna tipsa mig i hur jag utvecklar det?

Mvh Marta

Hej hej

Andreas är väldigt upptagen så här kring jul. Så jag svarar istället. Jag antar att du fortfarande pratar om frågan du ställde på vba forumet, dvs färga staplar baserat på deras värde.

Då kan du göra så här.

1. Gå in i editorn, alt + f11
2. I projektfönstret, högerklicka på projekt och lägg till modul.
3. I kodfönstret som nu dykt upp skriv kod du hittar längre ned.
4. Modifiera kod utefter dina behov. Just nu är koden inställd på att köra på bladet med index 1. Det är bladet som ligger längst till vänster. Om bladet flyttas ändras även index. Har du flera diagram på samma sida så är koden inställd på diagram med index 1, du får testa dig fram för att hitta rätt. Vidare är färgerna jag lade in ganska extrema eftersom jag har valt att använda maxgrön, maxröd osv. Goggla på RGB koder så kan du sätta dem själv efter färger du gillar.
Gränsvärdena är under 10, över 20, samt däremellan, det går självklart att ha fler parametrar om man vill ha fler färger. Det går då att bygga vidare med fler Case is satser, select satser väljer det första kriteriet som är uppfyllt, så man kan ha både under 10 och under 20 om man vill.

Denna kod triggas iinte automatiskt såsom andreas gjorde. Det går självklart att få den att göra det, men det kräver väldigt mycket undantagshantering, därav valde jag att göra på detta sätt istället. Du får därför lägga till en knapp/figur och koppla den till ditt makro.

Mvh
Christian

Option Explicit

Sub aChartFix()

Dim Pts As Points
Set Pts = Sheets(1).ChartObjects(1).Chart.SeriesCollection(1).Points
Dim sc As SeriesCollection: Set sc = Sheets(1).ChartObjects(1).Chart.SeriesCollection
Dim i As Integer
Dim vnt As Variant: vnt = sc(1).Values

For i = 1 To Pts.Count
Select Case vnt(i)
Case Is < 10
Pts(i).Interior.Color = RGB(255, 255, 0)
Case Is > 20
Pts(i).Interior.Color = RGB(255, 0, 0)
Case Else
Pts(i).Interior.Color = RGB(0, 255, 0)
End Select
Next i


End Sub