Hej!

Det låter helt klart som att det vore lättare att spara informationen i ett dolt blad i samma arbetsbok istället för i en textfil. Det under förutsättningen att data inte skall användas i något annat sammanhang utanför arbetsboken. Som jag förstår det vill du ha en inmatningsflik, en visningsflik samt en dataflik där all data sparas. Om vi börjar med inmatningsfliken (wsInput) så rekomenderar jag att du infogar en knapp (formulär) som du kan koppla till ett makro som sparar informationen som du ex. matar in i cell B6:F6. Om man gör en enklare variant på ett sådan makro skulle det ungefär se ut som nedan. Börja med att försöka få detta att fungera så kan vi ta övriga delar senare. Observera att jag döpt om flikarnas "codename" inne i VBA editorn så att inmatningsfliken heter wsInput istället för Blad1 och datafliken wsData istället för Blad3 etc.

Public Sub SaveData()
    Dim avntData As Variant
    Dim strNr As String
    Dim strDate As String
    Dim blnNrExist As Boolean
    Dim intRow As Integer
    Dim intLastRow As Integer
   
    avntData = wsInput.Range("B6:F6").Value
    strNr = wsInput.Range("B6")
    intLastRow = wsData.UsedRange.Rows.Count
   
    blnNrExist = False
    For intRow = 1 To intLastRow
        If wsData.Range("A" & intRow).Value = strNr Then
            strDate = wsData.Range("D" & intRow).Value
            blnNrExist = True
            Exit For
        End If
    Next intRow
   
    If blnNrExist Then
        If MsgBox("Detta nummer finns angivet den " & strDate & ", vill du skriva över?", vbYesNo) = vbYes Then
            wsData.Range("A" & intRow & ":E" & intRow) = avntData
            wsInput.Range("B6:F6").ClearContents
        Else
            wsInput.Range("B6").ClearContents
        End If
    Else
        wsData.Range("A" & intLastRow + 1 & ":E" & intLastRow + 1) = avntData
        wsInput.Range("B6:F6").ClearContents
    End If
End Sub

/Oskar